add_test(
  NAME tiny-convmem-mcp.smoke
  COMMAND "${CMAKE_COMMAND}"
    "-DSERVER=$<TARGET_FILE:tiny-convmem-mcp>"
    "-DINPUT=${CMAKE_CURRENT_SOURCE_DIR}/fixtures/smoke-input.jsonl"
    "-DDATA_DIR=${CMAKE_CURRENT_BINARY_DIR}/smoke-data"
    -P "${CMAKE_CURRENT_SOURCE_DIR}/smoke.cmake"
)

set_tests_properties(tiny-convmem-mcp.smoke PROPERTIES TIMEOUT 15)

add_executable(tiny-convmem-domain-test
  domain_test.c
  "${PROJECT_SOURCE_DIR}/src/domain/message.c"
  "${PROJECT_SOURCE_DIR}/src/domain/search.c"
)
target_include_directories(tiny-convmem-domain-test PRIVATE "${PROJECT_SOURCE_DIR}/src")
target_compile_features(tiny-convmem-domain-test PRIVATE c_std_17)
if(MSVC)
  target_compile_options(tiny-convmem-domain-test PRIVATE /utf-8 /W4)
endif()
add_test(NAME tiny-convmem-mcp.domain COMMAND tiny-convmem-domain-test)

add_executable(tiny-convmem-storage-test
  storage_test.c
  "${PROJECT_SOURCE_DIR}/src/domain/message.c"
  "${PROJECT_SOURCE_DIR}/src/storage/store.c"
)
target_include_directories(tiny-convmem-storage-test PRIVATE "${PROJECT_SOURCE_DIR}/src")
target_compile_features(tiny-convmem-storage-test PRIVATE c_std_17)
target_link_libraries(tiny-convmem-storage-test PRIVATE bcrypt)
if(MSVC)
  target_compile_options(tiny-convmem-storage-test PRIVATE /utf-8 /W4)
endif()
add_test(NAME tiny-convmem-mcp.storage COMMAND tiny-convmem-storage-test)

add_test(
  NAME tiny-convmem-mcp.lifecycle
  COMMAND "${CMAKE_COMMAND}"
    "-DSERVER=$<TARGET_FILE:tiny-convmem-mcp>"
    "-DWRITE_INPUT=${CMAKE_CURRENT_SOURCE_DIR}/fixtures/write-once.jsonl"
    "-DHEALTH_INPUT=${CMAKE_CURRENT_SOURCE_DIR}/fixtures/health.jsonl"
    "-DDATA_DIR=${CMAKE_CURRENT_BINARY_DIR}/lifecycle-data"
    -P "${CMAKE_CURRENT_SOURCE_DIR}/lifecycle.cmake"
)
set_tests_properties(tiny-convmem-mcp.lifecycle PROPERTIES TIMEOUT 15)

add_test(NAME tiny-convmem-mcp.requires-data-dir COMMAND $<TARGET_FILE:tiny-convmem-mcp>)
set_tests_properties(tiny-convmem-mcp.requires-data-dir PROPERTIES WILL_FAIL TRUE)